// The entire file can be run from the shell with
//     magma LinkComplementHelpers.m LinkComplement23.m
// or from within magma with
//     load "LinkComplementHelpers.m";
//     load "LinkComplement23.m";
// 

Bianchi23<g1,g2,g3,g4,g5> := Group<g1,g2,g3,g4,g5|
    g3^3,(g3*g2)^2,(g1,g2),(g4,g5),
    g5*g2^-1*g3^-1*g5^-1*g1^-1*g2^-1*g3^-1*g1,
    g4^-1*g5*g3*g2*g5^-1*g2*g4*g3>;

Bianchi23P := [[g2, g1], [g4, g5], [g4*g3*g2, g2^-1*g5*g3*g2]];

// Difference to arXiv version 1: changed Dehn-filling in first row
// and last column given to Expand from [ 1, 1] to [ 0, 1]. Both
// work but the latter is easier and consistent with Exp. Math paper.

print "";
print "<2, (1+sqrt(-23))/2>";

VerifyLink(
    Bianchi23, Bianchi23P,
    [[2,1,1],[1,0,2],[2,1,1]], 6,
    Expand(
        [ g3^0, g3^1, g3^2 ],
        [ [ [ 1, 0], [ 1, 0], [ 0, 1] ],
          [ [ 0, 1], [ 1, 0], [ 0, 1] ],
          [ [ 1, 0], [ 1, 0], [ 0, 1] ] ]));
    
print "";
print "<3, (1+sqrt(-23))/2>";

a:=g3*g2;
b:=(g3*g2)*g1*(g3*g2)*g1^-1*(g3*g2)^-1;

VerifyLink(
    Bianchi23, Bianchi23P,
    [[3,1,1],[3,1,1],[3,0,1]], 12,

    Expand([Id(Bianchi23), a, b, a * b],
           [ [ [ 1,-2], [ 1,-2], [ 1,-2], [ 0, 1] ],
             [ [ 0, 1], [ 0, 1], [-1, 1], [ 0, 1] ],
             [ [ 1, 1], [ 0, 1], [ 0, 1], [ 0, 1] ] ]));

// Difference to arXiv version 1: fixed print showing conjugate ideal.

print "";
print "<4, (3-sqrt(-23))/2>";

VerifyLink(
    Bianchi23, Bianchi23P,
    [[4,1,-1],[2,1,-2],[4,-1,1]], 24,
    Symmetrize(
        g2^2, 2,
        [[ <Id(Bianchi23),        [ 1,-4]>,
           <g3^-1*g2^2*g3,        [ 0, 1]> ],
         [ <Id(Bianchi23),        [ 0, 1]>,
           <g3^-1*g2^2*g3,        [ 0, 1]> ],
         [ <g3,                   [ 0, 1]>,
           <g3^-1*g2^2*g3^-1,     [ 0, 1]> ]],
        [[ <g3^-1,                [ 1,-4]>,
           <g3,                   [ 1,-4]> ],
         [ <g3^-1,                [ 0, 1]>,
           <g3,                   [ 0, 1]> ],
         [ <g3^-1,                [ 0, 1]>,
           <Id(Bianchi23),        [ 0, 1]> ]]));